Amiga News 95/Amiga News 95.iso/dpat/dpat94/amitel.install

Text File | 1995-05-22 | 5.8 KB | 296 lines

;*********************************************;
;                                             ;
; $VER: Installation d'AmiTEL v2.1 (22/05/95) ;
;                                             ;
;    Script Installer pour AmiTEL.         ;
;                                             ;
;*********************************************;

; Initialisations.

(set @app-name "AmiTEL")
(set UserLevel.old @user-level)
(set Language 16)
(set #WrongKickStart "\nAmiTEL ne fonctionne qu'avec un KickStart >= à 2.04.")

; Message de Bienvenue.

(complete 0)
(welcome "Bienvenue sur le programme d'installation d'AmiTEL v2.1."
     " Cette installation est réalisée avec le programme"
     " 'Installer' de Commodore pour les ordinateurs Amiga.\n")

; S'assurer que l'on utilise un KickStart >= à 2.04.

(if (< (/ (getversion) 65536) 37)
  (abort #WrongKickStart))

; Copie des fichiers exécutables et de la documentation d'AmiTEL.

(set Path.Source
  (tackon
    (askdir
      (prompt "\nSélectionnez le lecteur sur lequel se trouve AmiTEL.\n")
      (help @askdir-help)
      (default (pathonly @icon))
    )
    ""
  )
)

(set Path.Dest
  (tackon
    (askdir
      (prompt "\nSélectionnez ou créez un répertoire dans lequel vous"
          " voulez installer AmiTEL.\n")
      (help @askdir-help)
      (default "SYS:")
    )
    ""
  )
)

(copyfiles
  (prompt "\nSélectionnez les fichiers exécutables à installer:\n")
  (help @copyfiles-help)
  (source Path.Source)
  (dest   Path.Dest)
  (choices "AmiTEL"
           "Update"
           "BBTPro")
  (infos)
  (confirm)
)

(complete 10)

; Copie du fichier Exemple.vdt.

(if
  (exists "Exemple.vdt")
  (if
    (askbool
      (prompt "\nVoulez vous installer le fichier d'exemple d'AmiTEL ?")
      (help @askbool_help)
      (default 1)
    )

    (
      (copyfiles
        (prompt "\nSelectionnez le fichier à installer:\n")
        (help @copyfiles-help)
        (source Path.Source)
        (dest   Path.Dest)
        (choices "Exemple.vdt")
        (confirm)
      )
    )
  )
)

(complete 20)

; Copie du fichier clé d'enregistrement AmiTEL.key.

(if
  (exists "L/AmiTEL.key")
  (if
    (askbool
      (prompt "\nVoulez vous installer votre clé d'enregistrement ?")
      (help @askbool_help)
      (default 1)
    )

    (
      (copyfiles
        (prompt "\nSelectionnez le fichier à installer:\n")
        (help @copyfiles-help)
        (source "L")
        (dest   "L:")
        (choices "AmiTEL.key")
        (confirm)
      )
    )
  )
)

(complete 30)

; Suppression du fichier AmiTEL.cfg et des fonts obsolètes.

(if
  (exists "S:AmiTEL.cfg")
  (if
    (askbool
      (prompt "\nVoulez vous supprimer le fichier S:AmiTEL.cfg obsolète ?")
      (help @askbool_help)
      (default 1)
    )

    (
      (delete "S:AmiTEL.cfg")
    )
  )
)

(if
  (exists "FONTS:Minitel")
  (if
    (askbool
      (prompt "\nVoulez vous supprimer les fontes Minitel obsolètes ?")
      (help @askbool_help)
      (default 1)
    )

    (
      (delete "Fonts:Minitel/8")
      (delete "Fonts:Minitel/16")
      (delete "Fonts:Minitel")
      (delete "Fonts:Minitel.font")
      (delete "Fonts:Minitel16/8")
      (delete "Fonts:Minitel16/16")
      (delete "Fonts:Minitel16")
      (delete "Fonts:Minitel16.font")
      (delete "Fonts:Minitel80/8")
      (delete "Fonts:Minitel80")
      (delete "Fonts:Minitel80.font")
    )
  )
)

(complete 40)

; Copie des fichiers AmiTEL.guide.

(if
  (askbool
    (prompt "\nVoulez vous installer la documentation d'AmiTEL ?")
    (help @askbool_help)
    (default 1)
  )

  (
    (copyfiles
      (prompt "\nSelectionnez les fichiers à installer:\n")
      (help @copyfiles-help)
      (source Path.Source)
      (dest   Path.Dest)
      (choices "AmiTEL.guide"
               "AmiTEL.English.guide")
      (infos)
      (confirm)
    )
  )
)

(complete 50)

; Copie du fichier AmiTEL.catalog.

(if
  (askbool
    (prompt "\nVoulez vous installer la version anglaise d'AmiTEL ?")
    (help @askbool_help)
    (default 1)
  )

  (
    (copyfiles
      (prompt "\nSelectionnez le fichier à installer:\n")
      (help @copyfiles-help)
      (source "Locale/Catalogs/English")
      (dest   "Locale:Catalogs/English")
      (choices "AmiTEL.catalog")
      (confirm)
    )
  )
)

(complete 60)

; Copie des fichiers d'exemples ARexx.

(if
  (askbool
    (prompt "\nVoulez vous installer les fichiers d'exemples ARexx ?")
    (help @askbool_help)
    (default 1)
  )

  (
    (copyfiles
      (prompt "\nSelectionnez les fichiers à installer:\n")
      (help @copyfiles-help)
      (source "Rexx")
      (dest   "REXX:")
      (pattern "#?.rexx")
      (confirm)
    )
  )
)

(complete 70)

; Copie des fichiers XPRxxxxxx.library.

(if
  (askbool
    (prompt "\nVoulez vous installer les protocoles de téléchargement XPR ?")
    (help @askbool_help)
    (default 1)
  )

  (
    (copyfiles
      (prompt "\nSelectionnez les fichiers à installer:\n")
      (help @copyfiles-help)
      (source "Libs")
      (dest   "LIBS:")
      (pattern "xpr#?.library")
      (confirm)
    )
  )
)

(complete 80)

; Copie de la librairie ReqTools.

(message
  "\n"
  "Pour fonctionner, AmiTEL utilise la ReqTools.library.\n"
  "\n"
  "Avant de l'installer, je vais vérifier que vous n'avez "
  "pas une version plus récente de ReqTools.library.\n"
  "Si c'est le cas, je ne l'installerai pas.\n"
)

(copylib
  (prompt "\nVoulez vous copier la ReqTools.library dans LIBS: ?")
  (help @copylib-help)
  (source "Libs/reqtools.library")
  (dest "LIBS:")
  (confirm)
)

(complete 90)

; Mise à jour du fichier AmiTEL.phone.

(if
  (exists (cat Path.Dest "/AmiTEL.phone"))
  (message
     "\n\nIMPORTANT\n\n"
     "N'oubliez pas de mettre à jour votre fichier\n"
     "AmiTEL.phone en utlisant le commande 'Update'\n"
     "dès l'installation du programme terminée.\n"
  )
)

(complete 100)

; End of Program

(set @default_dest Path.Dest)
(exit)